A C shell konfigurációs fájljai
Amikor a C shell-t elindítjuk, az alapkatalógusunkban lévő .cshrc fájl tartalmát beolvassa és végrehajtja a shell. Ez a tevékenység minden egyes C shell indításakor végrehajtódik, tehát ha valamilyen oknál fogva több shell-t indítunk el egymás fölött, akkor annyiszor, ahány shell-t indítottunk. (Ugyanez igaz akkor is, ha egy ablakkezelő rendszerrel rendelkező gépen egy olyan új ablakot nyitottunk, amelyik C shell-t használ.)
Abban az esetben, ha az elindult C shell a bejelentkezési shell, a .cshrc lefutása után a .login fájl tartalmát is végrehajtja a rendszer, feltéve hogy létezik ilyen fájl az alapkatalógusunkban.
A login shell-ből való kilépéskor a .logout fájl tartalma is végrehajtódik (természetesen megint csak akkor, ha létezik ilyen fájl).
Látható, hogy ellentétben a Bourne shell konfigurációs mechanizmusával, itt nem egy-egy rendszer-, illetve felhasználó-specifikus konfigurációs fájl szerepel (/etc/profile, illetve $HOME/.profile), hanem két felhasználó-specifikus állomány. Mindez nem okoz különösebb gondot, mindkét rendszerrel megoldhatóak a tipikus konfigurációs problémák. Mivel a .cshrc minden shell indításakor lefut, ebben célszerű a shell-változók beállítását elvégezni, míg a .login fájlban az egyszeri, bejelentkezéssel kapcsolatos teendőket, például termináltípus- és paraméterek beállítása, postaellenőrzés stb.
Az alábbiakban egy tipikus .cshrc fájlt mutatunk be. Rendszerint azokat a konfigurálandó értékeket szokás itt beállítani, amelyek minden shell lefutásnál az applikációtól függően változhatnak, például keresési útvonal beállítása, a felhasználó által specifikált egyedi shell-változók, stb.
hp 22: cat .cshrc
# Default keresesi utvonal beallitasa:
set path=( /bin /usr/bin /usr/local/bin $home/bin . )
# C shell kornyezet beallitasa:
if ( $?prompt ) then # interaktiv shell
# nyilvantartott elozo parancsok
set history=20
# belepesek kozt megorzendo parancsok szama
set savehist=20
# rendszer neve
set system=`hostname`
# a parancs prompt definicioja
set prompt = "$system \!: "
# alias beallitasok:
alias h history
alias dir ls -al
endif
A .cshrc után végrehajtódó .login fájl elsősorban a globális parancsokat tartalmazza, azokat, amelyeket csak egyszer célszerű lefuttatni, a rendszerbe történő bejelentkezéskor. Az alábbi példa egy tipikus .login állományt mutat:
hp 23: cat .login
# idozona beallitas:
setenv TZ MET-1METDST
# postafiok beallitas:
setenv MAIL /usr/mail/demo
# terminal beallitas:
# default terminal lekerdezese es beallitasa
eval `tset -s -Q -m ':?hp' `
# terminalparameterek beallitasa
stty erase "^H" kill "^U" intr "^C" eof "^D" susp "^Z" hupcl ixon ixoff tostop cs8 -istrip
# tabulator-kezeles beallitasa
tabs
# shell kornyezet beallitas:
set noclobber # letezo fajl felulirasat letiltja
# globalis parancsok:
# altalanos kozlemenyek
news | more
Értelemszerűen ebbe a fájlba olyan programok kerülnek, amelyeket kilépéskor szándékozunk végrehajtatni. (Általában nem sok ilyen tevékenység akad; olyan gépeken, ahol nyilvántartják az egyes felhasználók által felhasznált gépidőt, vagy egyéb erőforrásokat, ezek felhasználásáról szokták kiíratni a statisztikát.)